cond.pony

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
class Cond[
  S: (Any #read & Equatable[S]),
  D: Any #share = None,
  V: Any #share = None]
  is RuleNodeWithBody[S, D, V]

  let _body: RuleNode[S, D, V]
  let _cond: {(Success[S, D, V]): (Bool, (String | None))} val

  new create(
    body': RuleNode[S, D, V],
    cond': {(Success[S, D, V]): (Bool, (String | None))} val)
  =>
    _body = body'
    _cond = cond'

  fun action(): (Action[S, D, V] | None) =>
    None

  fun body(): (this->(RuleNode[S, D, V]) | None) =>
    _body

  fun call(depth: USize, loc: Loc[S]): _RuleFrame[S, D, V] =>
    _CondFrame[S, D, V](this, depth, loc, _body, _cond)

class _CondFrame[S: (Any #read & Equatable[S]), D: Any #share, V: Any #share]
  is _Frame[S, D, V]

  let _rule: RuleNode[S, D, V] box
  let _depth: USize
  let _loc: Loc[S]
  let _body: RuleNode[S, D, V] box
  let _cond: {(Success[S, D, V]): (Bool, (String | None))} val

  new create(
    rule: RuleNode[S, D, V] box,
    depth: USize,
    loc: Loc[S],
    body: RuleNode[S, D, V] box,
    cond: {(Success[S, D, V]): (Bool, (String | None))} val)
  =>
    _rule = rule
    _depth = depth
    _loc = loc
    _body = body
    _cond = cond

  fun ref run(child_result: (Result[S, D, V] | None)): _FrameResult[S, D, V] =>
    match child_result
    | let success: Success[S, D, V] =>
      (let succeeded, let message) = _cond(success)
      if succeeded then
        _Dbg() and _Dbg.out(_depth, "= " + success.string())
        success
      else
        _Dbg() and _Dbg.out(_depth, "= failure: " + message.string())
        Failure[S, D, V](_rule, success.start, message)
      end
    | let failure: Failure[S, D, V] =>
      _Dbg() and _Dbg.out(_depth, "= " + failure.string())
      failure
    else
      _Dbg() and _Dbg.out(_depth, "COND @" + _loc.string())
      _body.call(_depth + 1, _loc)
    end