bind.pony

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
class Bind[
  S: (Any #read & Equatable[S]),
  D: Any #share = None,
  V: Any #share = None]
  is RuleNodeWithBody[S, D, V]

  let variable: Variable
  let _body: RuleNode[S, D, V]

  new create(
    variable': Variable,
    body': RuleNode[S, D, V])
  =>
    variable = variable'
    _body = body'

  fun action(): (Action[S, D, V] | None) =>
    None

  fun body(): (this->(RuleNode[S, D, V]) | None) =>
    _body

  fun call(depth: USize, loc: Loc[S]): _RuleFrame[S, D, V] =>
    _BindFrame[S, D, V](this, depth, loc, variable.name, _body)

class _BindFrame[S: (Any #read & Equatable[S]), D: Any #share, V: Any #share]
  is _Frame[S, D, V]

  let _rule: RuleNode[S, D, V] box
  let _depth: USize
  let _loc: Loc[S]
  let _name: String
  let _body: RuleNode[S, D, V] box

  new create(
    rule: RuleNode[S, D, V] box,
    depth: USize,
    loc: Loc[S],
    name: String,
    body: RuleNode[S, D, V] box)
  =>
    _rule = rule
    _depth = depth
    _loc = loc
    _name = name
    _body = body

  fun ref run(child_result: (Result[S, D, V] | None)): _FrameResult[S, D, V] =>
    match child_result
    | let success: Success[S, D, V] =>
      _Dbg() and _Dbg.out(_depth, "= " + _name + " := " + success.string())
      Success[S, D, V](_rule, success.start, success.next, [ success ])
    | let failure: Failure[S, D, V] =>
      _Dbg() and _Dbg.out(_depth, "= " + _name + " := " + failure.string())
      failure
    else
      _Dbg() and _Dbg.out(_depth, "BIND " + _name + " @" + _loc.string())
      _body.call(_depth + 1, _loc)
    end