string_util.pony

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
use "format"

primitive StringUtil
  fun is_ws(ch: U8): Bool =>
    (ch == ' ') or (ch == '\t') or (ch == '\r') or (ch == '\n') or (ch == 0)

  fun escape(orig: String box): String iso^ =>
    """Returns an "escaped" version of a string.""""

    let result: String iso = String(orig.size())
    for rune in orig.runes() do
      if rune < ' ' then
        let ch = U8.from[U32](rune)
        if rune == '\a' then
          result.append("\\a")
        elseif rune == '\b' then
          result.append("\\b")
        elseif rune == '\e' then
          result.append("\\e")
        elseif rune == '\f' then
          result.append("\\f")
        elseif rune == '\n' then
          result.append("\\n")
        elseif rune == '\r' then
          result.append("\\r")
        elseif rune == '\t' then
          result.append("\\t")
        elseif rune == '\v' then
          result.append("\\v")
        elseif rune == '\0' then
          result.append("\\0")
        elseif rune == '"' then
          result.append("\\\"")
        else
          result.append("\\x")
          result.append(Format.int[U32](rune, FormatHexBare where prec = 2))
        end
      elseif rune == '\\' then
        result.append("\\\\")
      elseif rune == '"' then
        result.append("\\\"")
      elseif rune < 128 then
        result.push(U8.from[U32](rune))
      elseif rune < 0xff then
        result.append("\\x")
        result.append(Format.int[U32](rune, FormatHexBare where prec = 2))
      elseif rune < 0xffff then
        result.append("\\u")
        result.append(Format.int[U32](rune, FormatHexBare where prec = 4))
      else
        result.append("\\u")
        result.append(Format.int[U32](rune, FormatHexBare where prec = 6))
      end
    end
    consume result

  fun url_encode(str: String box): String =>
    let result: String trn = String
    for ch in str.values() do
      if
        ( (ch >= 'a') and (ch <= 'z') ) or
        ( (ch >= 'A') and (ch <= 'Z') ) or
        ( (ch >= '0') and (ch <= '9') ) or
        ( ch == '/' ) or (ch == '_') or (ch == '-') or (ch == '.')
      then
        result.push(ch)
      else
        result.push('%')
        result.append(Format.int[U8](ch, FormatHexBare where prec = 2))
      end
    end
    consume result

  fun url_decode(str: String): String =>
    let result: String trn = String
    var i: USize = 0
    while i < str.size() do
      let ch: U8 = try str(i)? else '?' end
      if (ch == '%') and ((i + 2) < str.size()) then
        try
          let hex = str.trim(i + 1, i + 3)
          result.push(hex.u8(16)?)
          i = i + 2
        else
          result.push(ch)
        end
      else
        result.push(ch)
      end
      i = i + 1
    end
    consume result

  fun get_client_uri(path: String): String =>
    let str = path.clone() .> replace("\\", "/")
    "file:///" + url_encode(consume str)