eohippus_log_formatter.pony

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
use "format"
use "logger"
use "time"

class EohippusLogFormatter is LogFormatter
  fun apply(message: String, loc: SourceLoc): String =>
    (let seconds, let nanos) = Time.now()
    let millis =
      recover val
        Format.int[I64](nanos / 1_000_000 where width = 3, fill = '0')
      end
    let stamp =
      try
        PosixDate(seconds, nanos).format("%Y-%m-%d %H:%M:%S")?
      else
        "?"
      end

    var fname = loc.file()
    let line = recover val loc.line().string() end

    fname =
      try
        let index = USize.from[ISize](
          ifdef windows then
            fname.rfind("eohippus\\server\\")?
          else
            fname.rfind("eohippus/server/")?
          end)
        fname.trim(index + 16)
      else
        try
          let index = USize.from[ISize](
            ifdef windows then
              fname.rfind("eohippus\\")?
            else
              fname.rfind("eohippus/")?
            end)
          fname.trim(index + 9)
        else
          fname
        end
      end

    let buf: String trn = String
    buf.append("[")
    buf.append(stamp)
    buf.append(".")
    buf.append(millis)
    buf.append("Z] ")
    buf.append(fname)
    buf.append(":")
    buf.append(line)
    buf.append(": ")
    buf.append(message)
    consume buf