publish_diagnostics_params.pony

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
use "itertools"

use json = "../../../json"

interface val PublishDiagnosticsParams is NotificationParams
  fun val uri(): String
  fun val version(): (I128 | None) => None
  fun val diagnostics(): Array[Diagnostic] val

  fun val get_json(): json.Item =>
    let props = [ as (String, json.Item): ("uri", uri()) ]
    match version()
    | let n: I128 =>
      props.push(("version", n))
    end
    props.push(
      ( "diagnostics"
      , recover val
          json.Sequence.from_iter[Diagnostic](
            diagnostics().values(), { (diag) => diag.get_json() })
        end ))
    json.Object(props)

primitive DiagnosticError
  fun apply(): I128 => 1

primitive DiagnosticWarning
  fun apply(): I128 => 2

primitive DiagnosticInformation
  fun apply(): I128 => 3

primitive DiagnosticHint
  fun apply(): I128 => 4

type DiagnosticSeverity is
  ( DiagnosticError
  | DiagnosticWarning
  | DiagnosticInformation
  | DiagnosticHint )

primitive DiagnosticTagUnnecessary
  fun apply(): I128 => 1

primitive DiagnosticTagDeprecated
  fun apply(): I128 => 2

type DiagnosticTag is (DiagnosticTagUnnecessary | DiagnosticTagDeprecated)

interface val DiagnosticRelatedInformation
  fun val location(): Location
  fun val message(): String

  fun val get_json(): json.Item =>
    json.Object(
      [ as (String, json.Item):
        ("location", location().get_json())
        ("message", message()) ])

interface val Diagnostic
  fun val range(): Range
  fun val severity(): (DiagnosticSeverity | None)
  fun val code(): (I128 | String | None) => None
  fun val codeDescription(): (CodeDescription | None) => None
  fun val source(): (String | None) => "eohippus pony tools"
  fun val message(): String
  fun val tags(): (Array[DiagnosticTag] val | None) => None
  fun val relatedInformation()
    : (Array[DiagnosticRelatedInformation] val | None)
  =>
    None
  fun val data(): (json.Item | None) => None

  fun val get_json(): json.Item =>
    let props = [ as (String, json.Item): ("range", range().get_json()) ]
    match severity()
    | let s: DiagnosticSeverity =>
      props.push(("severity", s()))
    end
    match code()
    | let item: (I128 | String) =>
      props.push(("code", item))
    end
    match codeDescription()
    | let cd: CodeDescription =>
      props.push(("codeDescription", cd.get_json()))
    end
    match source()
    | let str: String =>
      props.push(("source", str))
    end
    props.push(("message", message()))
    match tags()
    | let tags_arr: Array[DiagnosticTag] val =>
      let seq =
        recover val
          json.Sequence.from_iter[DiagnosticTag](
            tags_arr.values(), {(t) => t() })
        end
      props.push(("tags", seq))
    end
    match relatedInformation()
    | let ri_arr: Array[DiagnosticRelatedInformation] val =>
      let seq =
        json.Sequence.from_iter[DiagnosticRelatedInformation](
          ri_arr.values(), {(ri) => ri.get_json() })
      props.push(("relatedInformation", seq))
    end
    match data()
    | let d: json.Item =>
      props.push(("data", d))
    end
    json.Object(props)

interface val CodeDescription
  fun val href(): String

  fun val get_json(): json.Item =>
    json.Object([ as (String, json.Item): ("href", href()) ])