definition_params.pony

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
use json = "../../../json"

interface val DefinitionParams is
  (TextDocumentPositionParams & WorkDoneProgressParams & PartialResultParams)

primitive ParseDefinitionParams
  fun apply(obj: json.Object val): (DefinitionParams | String) =>
    let textDocument' =
      match try obj("textDocument")? end
      | let td_obj: json.Object val =>
        match ParseTextDocumentIdentifier(td_obj)
        | let tdi: TextDocumentIdentifier =>
          tdi
        | let err: String =>
          return err
        end
      else
        return "DefinitionParams.textDocument must be a JSON object"
      end
    let position' =
      match try obj("position")? end
      | let pos_obj: json.Object val =>
        match ParsePosition(pos_obj)
        | let pos: Position =>
          pos
        | let err: String =>
          return err
        end
      else
        return "DefinitionParams.position must be a JSON object"
      end
    let workDoneToken' =
      match try obj("workDoneToken")? end
      | let n: I128 =>
        n
      | let s: String val =>
        s
      end
    let partialResultToken' =
      match try obj("partialResultToken")? end
      | let n: I128 =>
        n
      | let s: String val =>
        s
      end
    object val is DefinitionParams
      fun val textDocument(): TextDocumentIdentifier => textDocument'
      fun val position(): Position => position'
      fun val workDoneToken(): (ProgressToken | None) => workDoneToken'
      fun val partialResultToken(): (ProgressToken | None) =>
        partialResultToken'
    end