semantic_tokens_options.pony

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
use json = "../../../../json"

use ".."

interface val SemanticTokensOptions is (WorkDoneProgressOptions & ResultData)
  fun val legend(): SemanticTokensLegend
  fun val range(): (Bool | json.Object | None)
  fun val full(): (Bool | SemanticTokensFullOptions | None)

  fun val get_json_props(): Array[(String, json.Item)] =>
    let props = [ as (String, json.Item): ("legend", legend().get_json()) ]
    match workDoneProgress()
    | let bool: Bool =>
      props.push(("workDoneProgress", bool))
    end
    match range()
    | let bool: Bool =>
      props.push(("range", bool))
    | let obj: json.Object =>
      props.push(("range", obj))
    end
    match full()
    | let bool: Bool =>
      props.push(("full", bool))
    | let fo: SemanticTokensFullOptions =>
      props.push(("full", fo.get_json()))
    end
    props

  fun val get_json(): json.Item =>
    json.Object(get_json_props())

interface val SemanticTokensRegistrationOptions is
  ( SemanticTokensOptions &
    TextDocumentRegistrationOptions &
    StaticRegistrationOptions )
  fun val get_json(): json.Item =>
    let props = Array[(String, json.Item)]
    match id()
    | let str: String =>
      props.push(("id", str))
    end
    match documentSelector()
    | let ds: DocumentSelector =>
      let seq =
        json.Sequence.from_iter[DocumentFilter](
          ds.values(), {(filter) => filter.get_json() })
      props.push(("documentSelector", seq))
    end
    props.append(get_json_props())
    json.Object(props)

interface val SemanticTokensLegend
  fun val tokenTypes(): Array[String] val
  fun val tokenModifiers(): Array[String] val

  fun val get_json(): json.Item =>
    json.Object(
      [ as (String, json.Item):
        ("tokenTypes", recover val json.Sequence(tokenTypes()) end)
        ("tokenModifiers", recover val json.Sequence(tokenModifiers()) end) ])

interface val SemanticTokensFullOptions
  fun val delta(): (Bool | None)

  fun val get_json(): json.Item =>
    let props = Array[(String, json.Item)]
    match delta()
    | let bool: Bool =>
      props.push(("delta", bool))
    end
    json.Object(props)

primitive SemanticTokens
  fun apply(): Array[String] val =>
    [ "type"
      "class"
      "interface"
      "struct"
      "typeParameter"
      "parameter"
      "variable"
      "function"
      "method"
      "keyword"
      "comment"
      "string"
      "number"
      "operator"
      "decorator" ]

primitive SemanticModifiers
  fun apply(): Array[String] val =>
    [ "documentation" ]