tcp_channel.pony

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
use "logger"
use "net"

class TcpChannel is Channel
  let _log: Logger[String]
  var _connection: TCPConnection

  new create(
    log: Logger[String],
    auth: TCPConnectAuth,
    host: String,
    service: String,
    rpc_handler: Handler)
  =>
    _log = log
    _connection = TCPConnection(
      auth,
      recover TcpChannelConnectionNotify(log, rpc_handler) end,
      host,
      service)

  fun ref write(data: (String val | Array[U8] val)) =>
    _log(Fine) and _log.log(
      "writing " + data.size().string() + " bytes")
    _connection.write(data)

  fun ref flush() =>
    _log(Fine) and _log.log("flush")
    None

  fun ref close() =>
    _log(Fine) and _log.log("close")
    _connection.dispose()

class TcpChannelConnectionNotify is TCPConnectionNotify
  let _log: Logger[String]
  let _rpc_handler: Handler

  new create(log: Logger[String], rpc_handler: Handler) =>
    _log = log
    _rpc_handler = rpc_handler

  fun ref connecting(conn: TCPConnection ref, count: U32) =>
    _log(Fine) and _log.log("connecting")
    _rpc_handler.listening()

  fun ref connected(conn: TCPConnection ref) =>
    _log(Fine) and _log.log("connected")
    _rpc_handler.connected()

  fun ref connect_failed(conn: TCPConnection ref) =>
    _log(Fine) and _log.log("connect failed")
    _rpc_handler.connect_failed()

  fun ref auth_failed(conn: TCPConnection ref) =>
    _log(Fine) and _log.log("auth failed")
    _rpc_handler.connect_failed()

  fun ref received(
    conn: TCPConnection ref,
    data: Array[U8] iso,
    times: USize)
    : Bool
  =>
    _log(Fine) and _log.log("received " + data.size().string() + " bytes")
    _rpc_handler.data_received(consume data)
    true

  fun ref closed(conn: TCPConnection ref) =>
    _log(Fine) and _log.log("closed")
    _rpc_handler.closed()