workspace_edit_client_capabilities.pony

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
use json = "../../../../json"

use ".."

interface val WorkspaceEditClientCapabilities
  fun val documentChanges(): (Bool | None)
  fun val resourceOperations(): (Array[ResourceOperationKind] val | None)
  // fun val failureHandling(): (FailureHandlingKind | None)
  // fun val normalizesLineEndings(): (Bool | None)
  // fun val changeAnnotationSupport():
  //   (ChangeAnnotationSupportClientCapability | None)

primitive ParseWorkspaceEditClientCapabilities
  fun apply(obj: json.Object val): (WorkspaceEditClientCapabilities | String) =>
    let documentChanges' =
      try
        match obj("documentChanges")?
        | let b: Bool =>
          b
        else
          return "workspaceEdit.documentChanges must be of type boolean"
        end
      end
    let resourceOperations': (Array[ResourceOperationKind] val | None)  =
      try
        match obj("resourceOperations")?
        | let ro_seq: json.Sequence val =>
          let ops: Array[ResourceOperationKind] trn =
            Array[ResourceOperationKind]
          for item in ro_seq.values() do
            match ParseResourceOperationKind(item)
            | let rok: ResourceOperationKind =>
              ops.push(rok)
            | let err: String =>
              return err
            end
          end
          consume ops
        else
          return "workspaceEdit.resourceOperations must be an array"
        end
      end
    object val is WorkspaceEditClientCapabilities
      fun val documentChanges(): (Bool | None) => documentChanges'
      fun val resourceOperations(): (Array[ResourceOperationKind] val | None) =>
        resourceOperations'
    end

interface val ChangeAnnotationSupportClientCapability
  fun val groupsOnLabel(): (Bool | None)

primitive ParseChangeAnnotationSupportClientCapability
  fun apply(obj: json.Object val):
    (ChangeAnnotationSupportClientCapability | String)
  =>
    let groupsOnLabel' =
      try
        match obj("groupsOnLabel")?
        | let b: Bool =>
          b
        else
          return "changeAnnotationSupport.groupsOnLabel must be of type boolean"
        end
      end
    object val is ChangeAnnotationSupportClientCapability
      fun val groupsOnLabel(): (Bool | None) => groupsOnLabel'
    end