text_document_client_capabilities.pony

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
use json = "../../../../json"

use ".."

interface val TextDocumentClientCapabilities
  fun val definition(): (DefinitionClientCapabilities | None)
  fun val publishDiagnostics(): (PublishDiagnosticsClientCapabilities | None)

primitive ParseTextDocumentClientCapabilities
  fun apply(obj: json.Object val)
    : (TextDocumentClientCapabilities | String)
  =>
    let definition' =
      try
        match obj("definition")?
        | let d_obj: json.Object val =>
          match ParseDefinitionClientCapabilities(d_obj)
          | let d: DefinitionClientCapabilities =>
            d
          | let err: String =>
            return err
          end
        else
          return "textDocument.definition must be a JSON object"
        end
      end
    let publishDiagnostics' =
      try
        match obj("publishDiagnostics")?
        | let pd_obj: json.Object val =>
          match ParsePublishDiagnosticsClientCapabilities(pd_obj)
          | let pd: PublishDiagnosticsClientCapabilities =>
            pd
          | let err: String =>
            return err
          end
        else
          return "textDocument.publishDiagnostics must be a JSON object"
        end
      end
    object val is TextDocumentClientCapabilities
      fun val definition(): (DefinitionClientCapabilities | None) => definition'
      fun val publishDiagnostics()
        : (PublishDiagnosticsClientCapabilities | None)
      =>
        publishDiagnostics'
    end

interface val PublishDiagnosticsClientCapabilities
  fun val relatedInformation(): (Bool | None)
  fun val tagSupport(): (TagSupport | None)
  fun val versionSupport(): (Bool | None)
  fun val codeDescriptionSupport(): (Bool | None)
  fun val dataSupport(): (Bool | None)

primitive ParsePublishDiagnosticsClientCapabilities
  fun apply(obj: json.Object val)
    : (PublishDiagnosticsClientCapabilities | String)
  =>
    let relatedInformation' =
      match try obj("relatedInformation")? end
      | let bool: Bool =>
        bool
      | let item: json.Item =>
        return "publishDiagnostics.relatedInformation must be a boolean"
      end
    let tagSupport' =
      try
        match obj("tagSupport")?
        | let ts_obj: json.Object val =>
          match ParseTagSupport(ts_obj)
          | let ts: TagSupport =>
            ts
          | let err: String =>
            return err
          end
        else
          return "publishDiagnostics.tagSupport must be a JSON object"
        end
      end
    let versionSupport' =
      match try obj("versionSupport")? end
      | let bool: Bool =>
        bool
      | let item: json.Item =>
        return "publishDiagnostics.versionSupport must be a boolean"
      end
    let codeDescriptionSupport' =
      match try obj("codeDescriptionSupport")? end
      | let bool: Bool =>
        bool
      | let item: json.Item =>
        return "publishDiagnostics.codeDescriptionSupport must be a boolean"
      end
    let dataSupport' =
      match try obj("dataSupport")? end
      | let bool: Bool =>
        bool
      | let item: json.Item =>
        return "publishDiagnostics.dataSupport must be a boolean"
      end
    object val is PublishDiagnosticsClientCapabilities
      fun relatedInformation(): (Bool | None) => relatedInformation'
      fun tagSupport(): (TagSupport | None) => tagSupport'
      fun versionSupport(): (Bool | None) => versionSupport'
      fun codeDescriptionSupport(): (Bool | None) => codeDescriptionSupport'
      fun dataSupport(): (Bool | None) => dataSupport'
    end

interface val TagSupport
  fun val valueSet(): Array[DiagnosticTag] val

primitive ParseTagSupport
  fun apply(obj: json.Object val): (TagSupport | String) =>
    let valueSet': Array[DiagnosticTag] val =
      try
        match obj("valueSet")?
        | let vs_seq: json.Sequence val =>
          let values: Array[DiagnosticTag] trn = Array[DiagnosticTag]
          for item in vs_seq.values() do
            values.push(
              match item
              | let n: I128 if n == DiagnosticTagUnnecessary() =>
                DiagnosticTagUnnecessary
              | let n: I128 if n == DiagnosticTagDeprecated() =>
                DiagnosticTagDeprecated
              else
                return "tagSupport.valueSet.x must be (1 | 2)"
              end)
          end
          consume values
        else
          return "tagSupport.valueSet must be a JSON sequence"
        end
      else
        return "tagSupport.valueSet must be a JSON sequence"
      end
    object val is TagSupport
      fun val valueSet(): Array[DiagnosticTag] val => valueSet'
    end