client_capabilities.pony

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
use json = "../../../../json"

interface val ClientCapabilities
  fun val workspace(): (WorkspaceClientCapabilities | None)
  fun val textDocument(): (TextDocumentClientCapabilities | None)
  fun val general(): (GeneralClientCapabilities | None)
  fun val experimental(): (json.Item | None)

primitive ParseClientCapabilities
  fun apply(obj: json.Object val): (ClientCapabilities | String) =>
    let workspace' =
      try
        match obj("workspace")?
        | let ws_obj: json.Object val =>
          match ParseWorkspaceClientCapabilities(ws_obj)
          | let ws: WorkspaceClientCapabilities =>
            ws
          | let err: String =>
            return err
          end
        else
          return "clientCapabilities.workspace must be a JSON object"
        end
      end
    let textDocument' =
      try
        match obj("textDocument")?
        | let td_obj: json.Object val =>
          match ParseTextDocumentClientCapabilities(td_obj)
          | let td: TextDocumentClientCapabilities =>
            td
          | let err: String =>
            return err
          end
        else
          return "clientCapabilities.textDocument must be a JSON object"
        end
      end
    let general' =
      try
        match obj("general")?
        | let g_obj: json.Object val =>
          match ParseGeneralClientCapabilities(g_obj)
          | let g: GeneralClientCapabilities =>
            g
          | let err: String =>
            return err
          end
        else
          return "clientCapabilities.general must be a JSON object"
        end
      end
    let experimental': (json.Item val | None) =
      try
        recover val json.Clone(obj("experimental")?) end
      end
    object val is ClientCapabilities
      fun val workspace(): (WorkspaceClientCapabilities | None) => workspace'
      fun val textDocument(): (TextDocumentClientCapabilities | None) =>
        textDocument'
      fun val general(): (GeneralClientCapabilities | None) => general'
      fun val experimental(): (json.Item | None) => experimental'
    end