typedef_members.pony

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
use json = "../json"

class val TypedefMembers is NodeData
  """
    The members of a class-like type.
  """

  let fields: NodeSeqWith[TypedefField]
  let methods: NodeSeqWith[TypedefMethod]

  new val create(
    fields': NodeSeqWith[TypedefField],
    methods': NodeSeqWith[TypedefMethod])
  =>
    fields = fields'
    methods = methods'

  fun name(): String => "TypedefMembers"

  fun val clone(updates: ChildUpdateMap): NodeData =>
    TypedefMembers(
      _map[TypedefField](fields, updates),
      _map[TypedefMethod](methods, updates))

  fun add_json_props(node: Node box, props: Array[(String, json.Item)]) =>
    if fields.size() > 0 then
      props.push(("fields", node.child_refs(fields)))
    end
    if methods.size() > 0 then
      props.push(("methods", node.child_refs(methods)))
    end

primitive ParseTypedefMembers
  fun apply(obj: json.Object val, children: NodeSeq)
    : (TypedefMembers | String)
  =>
    let fields =
      match ParseNode._get_seq_with[TypedefField](
        obj,
        children,
        "fields",
        "TypedefMembers.fields must be a sequence of TypedefField",
        false)
      | let seq: NodeSeqWith[TypedefField] =>
        seq
      | let err: String =>
        return err
      end
    let methods =
      match ParseNode._get_seq_with[TypedefMethod](
        obj,
        children,
        "methods",
        "TypedefMembers.methods must be a sequence of TypedefMethod",
        false)
      | let seq: NodeSeqWith[TypedefMethod] =>
        seq
      | let err: String =>
        return err
      end
    TypedefMembers(fields, methods)