type_arrow.pony

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
use json = "../json"

class val TypeArrow is NodeData
  """
    A top-level type (possibly with an arrow).
  """

  // TODO: this is backwards
  let lhs: Node
  let rhs: (NodeWith[TypeType] | None)

  new val create(lhs': Node, rhs': (NodeWith[TypeType] | None)) =>
    lhs = lhs'
    rhs = rhs'

  fun name(): String => "TypeArrow"

  fun val clone(updates: ChildUpdateMap): NodeData =>
    TypeArrow(
      try updates(lhs)? else lhs end,
      _map_or_none[TypeType](rhs, updates))

  fun add_json_props(node: Node box, props: Array[(String, json.Item)]) =>
    props.push(("lhs", node.child_ref(lhs)))
    match rhs
    | let rhs': NodeWith[TypeType] =>
      props.push(("rhs", node.child_ref(rhs')))
    end

primitive ParseTypeArrow
  fun apply(obj: json.Object val, children: NodeSeq): (TypeArrow | String) =>
    let lhs =
      match ParseNode._get_child(
        obj,
        children,
        "lhs",
        "TypeArrow.lhs")
      | let node: Node =>
        node
      | let err: String =>
        return err
      else
        return "TypeArrow.lhs must be a Node"
      end
    let rhs =
      match ParseNode._get_child_with[TypeType](
        obj,
        children,
        "rhs",
        "TypeArrow.rhs must be a TypeType",
        false)
      | let node: NodeWith[TypeType] =>
        node
      | let err: String =>
        return err
      end
    TypeArrow(lhs, rhs)