src_file.pony

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
use json = "../json"
use parser = "../parser"

class val SrcFile is NodeData
  """
    A Pony source file.
  """

  let locator: parser.Locator
  let usings: NodeSeqWith[Using]
  let type_defs: NodeSeqWith[Typedef]

  new val create(
    locator': parser.Locator,
    usings': NodeSeqWith[Using],
    type_defs': NodeSeqWith[Typedef])
  =>
    locator = locator'
    usings = usings'
    type_defs = type_defs'

  fun name(): String => "SrcFile"

  fun val clone(updates: ChildUpdateMap): NodeData =>
    SrcFile(
      locator,
      _map[Using](usings, updates),
      _map[Typedef](type_defs, updates))

  fun add_json_props(node: Node box, props: Array[(String, json.Item)]) =>
    props.push(("locator", locator))
    if usings.size() > 0 then
      props.push(("usings", node.child_refs(usings)))
    end
    if type_defs.size() > 0 then
      props.push(("type_defs", node.child_refs(type_defs)))
    end

primitive ParseSrcFile
  fun apply(obj: json.Object val, children: NodeSeq): (SrcFile | String) =>
    let locator =
      match try obj("locator")? end
      | let str: String box =>
        str
      else
        return "SrcFile.locator must be a string"
      end
    let usings =
      match ParseNode._get_seq_with[Using](
        obj,
        children,
        "usings",
        "SrcFile.usings must be a sequence of Using",
        false)
      | let seq: NodeSeqWith[Using] =>
        seq
      | let err: String =>
        return err
      end
    let type_defs =
      match ParseNode._get_seq_with[Typedef](
        obj,
        children,
        "type_defs",
        "SrcFile.type_defs must be a sequence of Typedef",
        false)
      | let seq: NodeSeqWith[Typedef] =>
        seq
      | let err: String =>
        return err
      end
    SrcFile(locator.clone(), usings, type_defs)