literal_integer.pony

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
use json = "../json"

primitive DecimalInteger
primitive HexadecimalInteger
primitive BinaryInteger
type LiteralIntegerKind is (DecimalInteger | HexadecimalInteger | BinaryInteger)

class val LiteralInteger is NodeDataWithValue[LiteralInteger, U128]
  let _value: U128
  let kind: LiteralIntegerKind

  new val create(value': U128, kind': LiteralIntegerKind) =>
    _value = value'
    kind = kind'

  fun name(): String => "LiteralInteger"

  fun val clone(updates: ChildUpdateMap): NodeData =>
    this

  fun add_json_props(node: Node box, props: Array[(String, json.Item)]) =>
    let kind_str =
      match kind
      | DecimalInteger => "DecimalInteger"
      | HexadecimalInteger => "HexadecimalInteger"
      | BinaryInteger => "BinaryInteger"
      end
    props.push(("kind", kind_str))
    props.push(("value", I128.from[U128](_value)))

  fun value(): U128 => _value

primitive ParseLiteralInteger
  fun apply(obj: json.Object val, children: NodeSeq)
    : (LiteralInteger | String)
  =>
    let value =
      match try obj("value")? end
      | let n: I128 =>
        U128.from[I128](n)
      else
        return "LiteralInteger.value must be an integer"
      end
    let kind =
      match try obj("kind")? end
      | "DecimalInteger" =>
        DecimalInteger
      | "HexadecimalInteger" =>
        HexadecimalInteger
      | "BinaryInteger" =>
        BinaryInteger
      else
        return "LiteralInteger.kind must be a string"
      end
    LiteralInteger(value, kind)