literal_char.pony

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
use json = "../json"

primitive CharLiteral
primitive CharEscaped
primitive CharUnicode

type CharLiteralKind is (CharLiteral | CharEscaped | CharUnicode)

class val LiteralChar is NodeDataWithValue[LiteralChar, U32]
  """
    A character literal.
    - `kind`: either a single character 'x' or a standard escaped character, or
      a Unicode escaped character.
  """

  let _value: U32
  let kind: CharLiteralKind

  new val create(kind': CharLiteralKind, value': U32) =>
    _value = value'
    kind = kind'

  fun name(): String => "LiteralChar"

  fun val clone(updates: ChildUpdateMap): NodeData =>
    this

  fun add_json_props(node: Node box, props: Array[(String, json.Item)]) =>
    let kind_str =
      match kind
      | CharLiteral => "CharLiteral"
      | CharEscaped => "CharEscaped"
      | CharUnicode => "CharUnicode"
      end
    props.push(("kind", kind_str))
    let str = recover val String .> push_utf32(_value) end
    props.push(("value", str))

  fun value(): U32 => _value

primitive ParseLiteralChar
  fun apply(obj: json.Object val, children: NodeSeq): (LiteralChar | String) =>
    let kind =
      match try obj("kind")? end
      | let str: String box =>
        match str
        | "CharLiteral" =>
          CharLiteral
        | "CharEscaped" =>
          CharEscaped
        | "CharUnicode" =>
          CharUnicode
        else
          return "LiteralChar.kind must be " +
            "(CharLiteral | CharEscaped | CharUnicode)"
        end
      else
        return "LiteralChar.kind must be a string"
      end
    let value =
      match try obj("value")? end
      | let str: String box =>
        match try str.utf32(0)? end
        | (let int: U32, let _: U8) =>
          int
        else
          return "LiteralChar.value must be a valid Unicode character"
        end
      else
        return "LiteralChar.value must be a valid Unicode character"
      end
    LiteralChar(kind, value)