exp_if.pony

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
use json = "../json"

primitive IfExp
primitive IfDef
primitive IfType

type IfKind is (IfExp | IfDef | IfType)

class val ExpIf is NodeData
  """
    An `if` expression.
    - `kind`: `if`, `ifdef`, or `iftype`.
  """

  let kind: IfKind
  let conditions: NodeSeqWith[IfCondition]
  let else_block: (NodeWith[Expression] | None)

  new val create(
    kind': IfKind,
    conditions': NodeSeqWith[IfCondition],
    else_block': (NodeWith[Expression] | None))
  =>
    kind = kind'
    conditions = conditions'
    else_block = else_block'

  fun name(): String => "ExpIf"

  fun val clone(updates: ChildUpdateMap): NodeData =>
    ExpIf(
      kind,
      _map[IfCondition](conditions, updates),
      _map_or_none[Expression](else_block, updates))

  fun add_json_props(node: Node box, props: Array[(String, json.Item)]) =>
    let kind_str =
      match kind
      | IfExp => "IfExp"
      | IfDef => "IfDef"
      | IfType => "IfType"
      end
    props.push(("kind", kind_str))
    props.push(("conditions", node.child_refs(conditions)))
    match else_block
    | let block: Node =>
      props.push(("else_block", node.child_ref(block)))
    end

primitive ParseExpIf
  fun apply(obj: json.Object val, children: NodeSeq): (ExpIf | String) =>
    let kind =
      match try obj("kind")? end
      | let str: String box =>
        match str
        | "IfExp" =>
          IfExp
        | "IfDef" =>
          IfDef
        | "IfType" =>
          IfType
        else
          return "ExpIf.kind must be one of (IfExp | IfDef | IfType)"
        end
      else
        return "ExpIf.kind must be a string"
      end
    let conditions =
      match ParseNode._get_seq_with[IfCondition](
        obj,
        children,
        "conditions",
        "ExpIf.conditions must be a sequence of IfCondition")
      | let seq: NodeSeqWith[IfCondition] =>
        seq
      | let err: String =>
        return err
      end
    let else_block =
      match ParseNode._get_child_with[Expression](
        obj,
        children,
        "else_block",
        "ExpIf.else_block must be an Expression",
        false)
      | let node: NodeWith[Expression] =>
        node
      | let err: String =>
        return err
      end
    ExpIf(kind, conditions, else_block)

class val IfCondition is NodeData
  """
    A condition and then-block in an `if` expression (i.e. the initial `if` and
    `then` block; or subsequent `elseif` and `then` blocks).
  """
  let if_true: NodeWith[Expression]
  let then_block: NodeWith[Expression]

  new val create(
    if_true': NodeWith[Expression],
    then_block': NodeWith[Expression])
  =>
    if_true = if_true'
    then_block = then_block'

  fun name(): String => "IfCondition"

  fun val clone(updates: ChildUpdateMap): NodeData =>
    IfCondition(
      _map_with[Expression](if_true, updates),
      _map_with[Expression](then_block, updates))

  fun add_json_props(node: Node box, props: Array[(String, json.Item)]) =>
    props.push(("if_true", node.child_ref(if_true)))
    props.push(("then_block", node.child_ref(then_block)))

primitive ParseIfCondition
  fun apply(obj: json.Object val, children: NodeSeq): (IfCondition | String) =>
    let if_true =
      match ParseNode._get_child_with[Expression](
        obj,
        children,
        "if_true",
        "IfCondition.if_true must be an Expression")
      | let node: NodeWith[Expression] =>
        node
      | let err: String =>
        return err
      else
        return "IfCondition.if_true must be an Expression"
      end
    let then_block =
      match ParseNode._get_child_with[Expression](
        obj,
        children,
        "then_block",
        "IfCondition.then_block must be an Expression")
      | let node: NodeWith[Expression] =>
        node
      | let err: String =>
        return err
      else
        return "IfCondition.then_block must be an Expression"
      end
    IfCondition(if_true, then_block)