exp_for.pony

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
use json = "../json"

class val ExpFor is NodeData
  """
    A `for` loop.
  """

  let pattern: NodeWith[TuplePattern]
  let sequence: NodeWith[Expression]
  let body: NodeWith[Expression]
  let else_block: (NodeWith[Expression] | None)

  new val create(
    pattern': NodeWith[TuplePattern],
    sequence': NodeWith[Expression],
    body': NodeWith[Expression],
    else_block': (NodeWith[Expression] | None))
  =>
    pattern = pattern'
    sequence = sequence'
    body = body'
    else_block = else_block'

  fun name(): String => "ExpFor"

  fun val clone(updates: ChildUpdateMap): NodeData =>
    ExpFor(
      _map_with[TuplePattern](pattern, updates),
      _map_with[Expression](sequence, updates),
      _map_with[Expression](body, updates),
      _map_or_none[Expression](else_block, updates))

  fun add_json_props(node: Node box, props: Array[(String, json.Item)]) =>
    props.push(("pattern", node.child_ref(pattern)))
    props.push(("sequence", node.child_ref(sequence)))
    props.push(("body", node.child_ref(body)))
    match else_block
    | let else_block': NodeWith[Expression] =>
      props.push(("else_block", node.child_ref(else_block')))
    end

primitive ParseExpFor
  fun apply(obj: json.Object val, children: NodeSeq): (ExpFor | String) =>
    let pattern =
      match ParseNode._get_child_with[TuplePattern](
        obj,
        children,
        "pattern",
        "ExpFor.pattern must be a TuplePattern")
      | let node: NodeWith[TuplePattern] =>
        node
      | let err: String =>
        return err
      else
        return "ExpFor.pattern must be a TuplePattern"
      end
    let sequence =
      match ParseNode._get_child_with[Expression](
        obj,
        children,
        "sequence",
        "ExpFor.sequence must be an Expression")
      | let node: NodeWith[Expression] =>
        node
      | let err: String =>
        return err
      else
        return "ExpFor.sequence must be an Expression"
      end
    let body =
      match ParseNode._get_child_with[Expression](
        obj,
        children,
        "body",
        "ExpFor.body must be an Expression")
      | let node: NodeWith[Expression] =>
        node
      | let err: String =>
        return err
      else
        return "ExpFor.body must be an Expression"
      end
    let else_block =
      match ParseNode._get_child_with[Expression](
        obj,
        children,
        "else_block",
        "ExpFor.else_block must be an Expression",
        false)
      | let node: NodeWith[Expression] =>
        node
      | let err: String =>
        return err
      end
    ExpFor(pattern, sequence, body, else_block)