exp_array.pony

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
use json = "../json"

class val ExpArray is NodeData
  """
    An array literal.
    - `array_type`: the explicit type of the array elements, if any.
    - `body`: will usually be an `ExpSequence`.
  """
  let array_type: (NodeWith[TypeType] | None)
  let body: (NodeWith[Expression] | None)

  new val create(
    array_type': (NodeWith[TypeType] | None),
    body': (NodeWith[Expression] | None))
  =>
    array_type = array_type'
    body = body'

  fun name(): String => "ExpArray"

  fun val clone(updates: ChildUpdateMap): NodeData =>
    ExpArray(
      _map_or_none[TypeType](array_type, updates),
      _map_or_none[Expression](body, updates))

  fun add_json_props(node: Node box, props: Array[(String, json.Item)]) =>
    match array_type
    | let array_type': NodeWith[TypeType] =>
      props.push(("type", node.child_ref(array_type')))
    end
    match body
    | let body': NodeWith[Expression] =>
      props.push(("body", node.child_ref(body')))
    end

primitive ParseExpArray
  fun apply(obj: json.Object val, children: NodeSeq): (ExpArray | String) =>
    let array_type =
      match ParseNode._get_child_with[TypeType](
        obj,
        children,
        "type",
        "ExpArray.type must be a TypeType",
        false)
      | let node: NodeWith[TypeType] =>
        node
      | let err: String =>
        return err
      end
    let body =
      match ParseNode._get_child_with[Expression](
        obj,
        children,
        "body",
        "ExpArray.body must be an Expression")
      | let node: NodeWith[Expression] =>
        node
      | let err: String =>
        return err
      end
    ExpArray(array_type, body)