call_args.pony

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
use json = "../json"

class val CallArgs is NodeData
  """
    The arguments (actual parameters) of a method call.
    - `pos`: positional arguments.
    - `named`: named arguments (should all be assignment expressions).
  """

  let pos: NodeSeqWith[Expression]
  let named: NodeSeqWith[Expression]

  new val create(
    pos': NodeSeqWith[Expression],
    named': NodeSeqWith[Expression])
  =>
    pos = pos'
    named = named'

  fun name(): String => "CallArgs"

  fun val clone(updates: ChildUpdateMap): NodeData =>
    CallArgs(_map[Expression](pos, updates), _map[Expression](named, updates))

  fun add_json_props(node: Node box, props: Array[(String, json.Item)]) =>
    if pos.size() > 0 then
      props.push(("positional", node.child_refs(pos)))
    end
    if named.size() > 0 then
      props.push(("named", node.child_refs(named)))
    end

primitive ParseCallArgs
  fun apply(obj: json.Object val, children: NodeSeq): (CallArgs | String) =>
    let positional =
      match ParseNode._get_seq_with[Expression](
        obj,
        children,
        "positional",
        "CallArgs.positional must refer to Expressions",
        false)
      | let seq: NodeSeqWith[Expression] =>
        seq
      | let err: String =>
        return err
      end
    let named =
      match ParseNode._get_seq_with[Expression](
        obj,
        children,
        "named",
        "CallArgs.named must refer to Expressions",
        false)
      | let seq: NodeSeqWith[Expression] =>
        seq
      | let err: String =>
        return err
      end
    CallArgs(positional, named)