src_item.pony

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
use "collections"
use "files"

use ast = "../ast"
use parser = "../parser"

primitive AnalysisStart
  fun apply(): USize => 0

primitive AnalysisParse
  fun apply(): USize => 1

primitive AnalysisScope
  fun apply(): USize => 2

primitive AnalysisLint
  fun apply(): USize => 3

primitive AnalysisUpToDate
  fun apply(): USize => 4

primitive AnalysisError
  fun apply(): USize => USize.max_value()

type SrcItemState is
  ( AnalysisStart
  | AnalysisParse
  | AnalysisScope
  | AnalysisLint
  | AnalysisUpToDate
  | AnalysisError )

trait SrcItem
  fun get_canonical_path(): FilePath
  fun get_state(): SrcItemState
  fun ref set_state(state': SrcItemState)

class SrcFileItem is SrcItem
  let canonical_path: FilePath

  let cache_path: FilePath
  var cache_prefix: String = ""

  var parent_package: (SrcPackageItem | None) = None
  let dependencies: Array[SrcItem] = []

  var task_id: USize = 0
  var state: SrcItemState = AnalysisStart

  var is_open: Bool = false
  var schedule: (I64, I64) = (0, 0)
  var parse: (parser.Parser | None) = None
  var syntax_tree: (ast.Node | None) = None
  var scope: (Scope | None) = None

  var node_indices: MapIs[ast.Node, USize] val = node_indices.create()
  var nodes_by_index: Map[USize, ast.Node] val = nodes_by_index.create()

  var scope_indices: MapIs[Scope, USize] val = scope_indices.create()
  var scopes_by_index: Map[USize, Scope] val = scopes_by_index.create()

  new create(canonical_path': FilePath, cache_path': FilePath) =>
    canonical_path = canonical_path'
    cache_path = cache_path'

  fun get_canonical_path(): FilePath => canonical_path
  fun get_state(): SrcItemState => state
  fun ref set_state(state': SrcItemState) => state = state'

  fun ref make_indices() =>
    match syntax_tree
    | let node: ast.Node =>
      (node_indices, nodes_by_index) =
        recover val
          let ni = MapIs[ast.Node, USize]
          let nbi = Map[USize, ast.Node]
          var next_index: USize = 0
          _make_node_indices(
            node, ni, nbi, { ref () => next_index = next_index + 1 })
          (ni, nbi)
        end
    end
    match scope
    | let scope': Scope =>
      (scope_indices, scopes_by_index) =
        recover val
          let si = MapIs[Scope, USize]
          let sbi = Map[USize, Scope]
          _make_scope_indices(scope', si, sbi)
          (si, sbi)
        end
    end

  fun tag _make_node_indices(
    node: ast.Node,
    ni: MapIs[ast.Node, USize],
    nbi: Map[USize, ast.Node],
    get_next: { ref (): USize })
  =>
    let index = get_next()
    ni(node) = index
    nbi(index) = node
    for child in node.children().values() do
      _make_node_indices(child, ni, nbi, get_next)
    end

  fun tag _make_scope_indices(
    scope': Scope,
    si: MapIs[Scope, USize],
    sbi: Map[USize, Scope])
  =>
    let index = scope'.index
    si(scope') = index
    sbi(index) = scope'
    for child in scope'.children.values() do
      _make_scope_indices(child, si, sbi)
    end

  fun ref compact() =>
    syntax_tree = None
    scope = None
    node_indices = node_indices.create()
    nodes_by_index = nodes_by_index.create()
    scope_indices = scope_indices.create()
    scopes_by_index = scopes_by_index.create()

class SrcPackageItem is SrcItem
  let canonical_path: FilePath

  let cache_path: FilePath
  var cache_prefix: String = ""

  var is_workspace: Bool = false
  var parent_package: (SrcPackageItem | None) = None
  let dependencies: Array[SrcItem] = []

  var task_id: USize = 0
  var state: SrcItemState = AnalysisStart

  new create(canonical_path': FilePath, cache_path': FilePath) =>
    canonical_path = canonical_path'
    cache_path = cache_path'

  fun get_canonical_path(): FilePath => canonical_path
  fun get_state(): SrcItemState => state
  fun ref set_state(state': SrcItemState) => state = state'